update Generic Master bas5

src/module/Module_Common.bas

@@ -22,6 +22,116 @@ Function GetLastDataRow(ByVal ws As Worksheet, ByVal columnNum As Long) As Long
     GetLastDataRow = ws.Cells(ws.Rows.Count, columnNum).End(xlUp).Row
 End Function
 
+' @return dict : key = keyCol，value = Array
+' @param sheetName
+' @param keyCol    
+' @param valueCols     Array(4,5,6)
+' @param startRow      default is 7
+Function LoadLookup( _
+    ByVal sheetName As String, _
+    ByVal keyCol As Long, _
+    ByVal valueCols As Variant, _
+    Optional ByVal startRow As Long = 7 _
+) As Object
+    
+    ' --- validate ---
+    If Trim(sheetName) = "" Then Exit Function
+    If Not IsArray(valueCols) Then
+        valueCols = Array(valueCols)
+    End If
+    Dim nValCols As Long: nValCols = UBound(valueCols) - LBound(valueCols) + 1
+    If nValCols = 0 Then Exit Function
+    
+    ' --- obtain worksheet ---
+    On Error Resume Next
+    Dim ws As Worksheet: Set ws = ThisWorkbook.Worksheets(sheetName)
+    On Error GoTo 0
+    If ws Is Nothing Then Exit Function
+    
+    ' --- obtain data（based on keyCol）---
+    Dim lastRow As Long: lastRow = ws.Cells(ws.Rows.Count, keyCol).End(xlUp).Row
+    If lastRow < startRow Then Exit Function
+    
+    ' --- prepare col ---
+    Dim minCol As Long: minCol = keyCol
+    Dim maxCol As Long: maxCol = keyCol
+    Dim i As Long
+    For i = LBound(valueCols) To UBound(valueCols)
+        If Not IsNumeric(valueCols(i)) Then Exit Function
+        Dim colNum As Long: colNum = CLng(valueCols(i))
+        If colNum < 1 Then Exit Function
+        If colNum < minCol Then minCol = colNum
+        If colNum > maxCol Then maxCol = colNum
+    Next i
+    
+    ' --- read ---
+    Dim dataRange As Range
+    Set dataRange = ws.Range(ws.Cells(startRow, minCol), ws.Cells(lastRow, maxCol))
+    Dim data As Variant: data = dataRange.Value
+
+    ' --- Ensure data is a 2D array ---
+    If Not IsArray(data) Then
+        ' Single cell case
+        Dim temp As Variant
+        ReDim temp(1 To 1, 1 To (maxCol - minCol + 1))
+        temp(1, 1) = data
+        data = temp
+    End If
+    
+    ' --- build ---
+    Dim keyOffset As Long: keyOffset = keyCol - minCol + 1
+    Dim valOffsets() As Long: ReDim valOffsets(0 To nValCols - 1)
+    For i = 0 To nValCols - 1
+        valOffsets(i) = valueCols(LBound(valueCols) + i) - minCol + 1
+    Next i
+    
+    ' --- write into  ---
+    Dim dict As Object: Set dict = CreateObject("Scripting.Dictionary")
+    dict.CompareMode = vbTextCompare
+    
+    Dim r As Long
+    For r = 1 To UBound(data, 1)
+        Dim key As String: key = Trim(data(r, keyOffset))
+        If key <> "" Then
+            Dim vals() As String: ReDim vals(0 To nValCols - 1)
+            Dim j As Long
+            For j = 0 To nValCols - 1
+                vals(j) = Trim(data(r, valOffsets(j)))
+            Next j
+            dict(key) = vals
+        End If
+    Next r
+    
+    Set LoadLookup = dict
+End Function
+
+Function GetLastDataRowInRange(ws As Worksheet, ByVal startCol As Long, ByVal endCol As Long, Optional ByVal startRow As Long = 7) As Long
+    ' --- validate ---
+    If startCol < 1 Then
+        Err.Raise 1001, "GetLastDataRowInRange", "startCol must >= 1"
+    End If
+    If endCol < 1 Then
+        Err.Raise 1002, "GetLastDataRowInRange", "endCol must >= 1"
+    End If
+    If endCol < startCol Then
+        Err.Raise 1003, "GetLastDataRowInRange", "endCol must >= startCol"
+    End If
+    If startRow < 1 Then
+        Err.Raise 1004, "GetLastDataRowInRange", "startRow must >= 1"
+    End If
+
+    ' --- query max row ---
+    Dim colIndex As Long, lastRow As Long, maxRow As Long
+    
+    maxRow = startRow - 1
+    For colIndex = startCol To endCol
+        lastRow = ws.Cells(ws.Rows.Count, colIndex).End(xlUp).Row
+        If lastRow > maxRow Then maxRow = lastRow
+    Next colIndex
+    
+    GetLastDataRowInRange = maxRow
+End Function
+
 Sub ClearDataRows(ByVal ws As Worksheet, ByVal startRow As Long, ByVal columnNum As Long)
     Dim lastRow As Long
     lastRow = ws.Cells(ws.Rows.Count, columnNum).End(xlUp).Row